凹凸映射
使用一张纹理来修改模型表面的法线,该方法不会真的改变模型的顶点位置。
通常两种办法:
第一种利用高度纹理模拟表面位移,然后得到修改后的法线值——高度映射。
第二种利用法线纹理,直接得到表面法线——法线映射。——通常使用该方法。
法线纹理
法线分量范围:[-1,1],需要通过pixel=(normal+1)/2 放缩到[0,1]才能存储到纹理图中,因此在采样时需要做一次反映射:normal=pixel×2-1。
法线方向的选择可以选择模型空间(实现简单+突变较少)下的或者模型顶点切线空间(自由度高+可进行UV动画+可重用+可压缩(只存储xy))下的:
模型空间下,坐标空间相同但是法线各异所以看起来五颜六色
切线空间下,坐标空间不同,法线在各自的坐标空间中,若该点法线方向未改变,则就是切线空间下的z轴方向(0,0,1)——映射成(0.5,0.5,1)——代表了法线扰动方向。
在切线空间下计算光照(效率高)
Shader "Custom/切线空间下法线映射"
{
Properties
{
_Color ("Color", Color) = (1,1,1,1)
_MainTex ("Albedo (RGB)", 2D) = "white" {}
_BumpTex("Normal Map",2D)="white"{}
_BumpScale("Bump Scale",Float)=1.0//控制凹凸程度
_Specular("Specular",Color)=(1,1,1,1)
_Gloss("Gloss",Range(8.0,256))=20
}
SubShader
{
Pass{
Tags{"LightMode"="ForwardBase"}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _BumpTex;
float4 _BumpTex_ST;
float _BumpScale;
fixed4 _Specular;
float _Gloss;
struct a2v{
float4 vertex:POSITION;
float3 normal:NORMAL;
float4 tangent:TANGENT;
float4 texcoord:TEXCOORD;
};
struct v2f{
float4 pos:SV_POSITION;
float4 uv:TEXCOORD0;
float3 lightDir:TEXCOORD1;
float3 ViewDir:TEXCOORD2;
};
v2f vert(a2v v){
v2f o;
//计算裁剪空间下的顶点坐标
o.pos= UnityObjectToClipPos(v.vertex);
//计算两张纹理的uv值(加上缩放和偏移)
o.uv.xy = v.texcoord.xy*_MainTex_ST.xy+_MainTex_ST.zw;
o.uv.zw = v.texcoord.xy*_BumpTex_ST.xy+_BumpTex_ST.zw;
//计算从世界空间转换到切线空间的变换矩阵,已知切线在世界下,按列放——切线到世界,按行放——世界到切线:
float3 worldNormal=UnityObjectToWorldNormal(v.normal);
float3 worldTangent=UnityObjectToWorldDir(v.tangent.xyz);
float3 worldBinormal=cross(worldNormal,worldTangent)*v.tangent.w;
float3x3 worldToTangent=float3x3(worldTangent,worldBinormal,worldNormal);
//将世界空间下的光线和视线变换到切线空间下
o.lightDir=mul(worldToTangent, WorldSpaceLightDir(v.vertex));
o.ViewDir=mul(worldToTangent,WorldSpaceViewDir(v.vertex));
return o;
}
fixed4 frag(v2f i) : SV_Target {
//采样得到切线空间下的切线值
fixed4 packedNormal = tex2D(_BumpTex, i.uv.zw);
//进行反映射
fixed3 tangentNormal=UnpackNormal(packedNormal);
//根据凹凸程度进行修改
tangentNormal.xy *= _BumpScale;
//因为normal为单位向量,根据xy计算z
tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));
//得到归一化切线空间下的视线和光线
fixed3 tangentLightDir = normalize(i.lightDir);
fixed3 tangentViewDir = normalize(i.ViewDir);
//得到主纹理的颜色作为反射率
fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
//计算环境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
//采用Lambert模型计算漫反射部分
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));
//采用Blinn模型计算高光反射部分
fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(tangentNormal, halfDir)), _Gloss);
//得出最终的颜色
return fixed4(ambient + diffuse + specular, 1.0);
}
ENDCG
}
}
FallBack "Diffuse"
}
效果:
在世界空间下计算光照(通用性高)
Shader "Custom/世界空间下法线映射"
{
Properties
{
_Color ("Color", Color) = (1,1,1,1)
_MainTex ("Albedo (RGB)", 2D) = "white" {}
_BumpTex("Normal Map",2D)="white"{}
_BumpScale("Bump Scale",Float)=1.0//控制凹凸程度
_Specular("Specular",Color)=(1,1,1,1)
_Gloss("Gloss",Range(8.0,256))=20
}
SubShader
{
Pass{
Tags{"LightMode"="ForwardBase"}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _BumpTex;
float4 _BumpTex_ST;
float _BumpScale;
fixed4 _Specular;
float _Gloss;
struct a2v{
float4 vertex:POSITION;
float3 normal:NORMAL;
float4 tangent:TANGENT;
float4 texcoord:TEXCOORD;
};
struct v2f{
float4 pos:SV_POSITION;
float4 uv:TEXCOORD0;
//构造从切线空间到模型空间的矩阵
float4 TtoWorld1:TEXCOORD1;
float4 TtoWorld2:TEXCOORD2;
float4 TtoWorld3:TEXCOORD3;
};
v2f vert(a2v v){
v2f o;
//计算裁剪空间下的顶点坐标
o.pos= UnityObjectToClipPos(v.vertex);
//计算两张纹理的uv值(加上缩放和偏移)
o.uv.xy = v.texcoord.xy*_MainTex_ST.xy+_MainTex_ST.zw;
o.uv.zw = v.texcoord.xy*_BumpTex_ST.xy+_BumpTex_ST.zw;
//计算从切线空间转换到世界空间的变换矩阵,已知切线在世界下,按列放——切线到世界,按行放——世界到切线:
float3 worldNormal=UnityObjectToWorldNormal(v.normal);
float3 worldTangent=UnityObjectToWorldDir(v.tangent.xyz);
float3 worldBinormal=cross(worldNormal,worldTangent)*v.tangent.w;
//在构成的同时顺便存储世界空间下的顶点坐标
float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
o.TtoWorld1=float4(worldTangent.x,worldBinormal.x,worldNormal.x,worldPos.x);
o.TtoWorld2=float4(worldTangent.y,worldBinormal.y,worldNormal.y,worldPos.y);
o.TtoWorld3=float4(worldTangent.z,worldBinormal.z,worldNormal.z,worldPos.z);
return o;
}
fixed4 frag(v2f i) : SV_Target {
//获得世界空间中的顶点坐标
float3 worldPos = float3(i.TtoWorld1.w, i.TtoWorld2.w, i.TtoWorld3.w);
//采样得到切线空间下的切线值
fixed4 packedNormal = tex2D(_BumpTex, i.uv.zw);
//进行反映射
fixed3 tangentNormal=UnpackNormal(packedNormal);
//根据凹凸程度进行修改
tangentNormal.xy *= _BumpScale;
//因为normal为单位向量,根据xy计算z
tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));
//将切线空间下的normal转换到世界空间下
fixed3 worldNormal=normalize(half3(dot(i.TtoWorld1.xyz, tangentNormal), dot(i.TtoWorld2.xyz, tangentNormal), dot(i.TtoWorld3.xyz, tangentNormal)));
//得到归一化世界空间下的视线和光线
fixed3 lightDir = normalize(UnityWorldSpaceLightDir(worldPos));
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));
//得到主纹理的颜色作为反射率
fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
//计算环境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
//采用Lambert模型计算漫反射部分
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, lightDir));
//采用Blinn模型计算高光反射部分
fixed3 halfDir = normalize(lightDir + viewDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
//得出最终的颜色
return fixed4(ambient + diffuse + specular, 1.0);
}
ENDCG
}
}
FallBack "Diffuse"
}
效果:
注意在unity中,若把法线纹理的纹理类型选择为normal map,则在采样时需要使用UnpackNormal函数来得到正确的法线方向。因为这种纹理unity可以根据平台对纹理进行压缩。高度映射时除了设置成normal map,还需要勾选create from grayscale,Unity会根据高度图来生成一张切线空间下的法线纹理。